node-cli-template/flake.nix

{
  description = "name-placeholder";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    flake-parts.url = "github:hercules-ci/flake-parts";
  };

  outputs = inputs:
    inputs.flake-parts.lib.mkFlake { inherit inputs; } (
      {
        systems = [ "x86_64-linux" ];

        perSystem = { config, system, pkgs, lib, ... }:
          let
            runtimeDeps = [ ]; # e. g. pkgs.jq
            runtimePath = lib.makeSearchPath "bin" runtimeDeps;

            basePackage = {
              pname = "name-placeholder";
              version = "0.1.0";
              src = ./.;
              npmDepsHash = "sha256-EvM5ZyNQEW8RYFCfI7Bkju1qL+1y8nleXPAX3IKce78=";
              npmBuildScript = "build";
            };
          in
            {
              # runtime deps included
              packages.bundled = pkgs.buildNpmPackage (basePackage // {
                makeWrapperArgs = [ "--prefix" "PATH" ":" runtimePath ];
              });

              packages.default = config.packages.bundled;

              packages.unbundled = pkgs.buildNpmPackage basePackage;

              devShells.default = pkgs.mkShell {
                packages = with pkgs;
                  [ nodejs typescript typescript-language-server ];
              };

              formatter = pkgs.nixpkgs-fmt;
            };
      }
    );
}